迷走の果て・Tiny Objects

迷走する日々の覚え書きです。自分で分かってることは省略してますので、念のため。

2端子温度センサLMT01を試す(8)Arduinoとの接続・最終編(多分)

前回の記事で表示がばたつくと書きましたがスケッチのミスでした。

最初にLMT01を試したのはPSoC1でした、抵抗1本で割りと簡単に繋がったので、Arduinoでも出来るのではないかと思ったのですが、結構振り回されました。
ようやく抵抗1本で繋がりました。
写真では抵抗を3本使ってますが、必要な値のが見つからなかったので直並列してます。
LMT01_ArduinoInternalComp_B.jpg

回路図、というほどのことはありませんが・・・。
D7につなぎます、スケッチを変更すればアナログ入力も使えるようになりますが、そうすると多分analogRead()が使えなくなると思います(未確認)

ついでにトランジスタによる接続も試してみました(回路図右)。この場合任意のデジタル入力に接続できます。内臓コンパレータは使いません。
LMT01_ArduinoInCompBG回路

ATmegaコンパレータ

コンパレータの+入力に内部基準電圧(1.1V)を使うようにしました、これで外付け部品は抵抗1本で済みます。
抵抗値は
1.1V÷((34μA+125μA)÷2)=13.8KΩ
となります、ノイズマージン確保のためです。(34μAはLMT01 のローレベル電流、125μAはハイレベル電流です。)
とはいえ電流値はばらつくので厳密にする必要はなく、13.KΩか15KΩで大丈夫でしょう。
手持ちがなかったので6.8KΩパラに10KΩをつなぎました。ちなみに10KΩでは動作しませんでした。


スケッチです、回路図左用です。

// LMT01をArduinoにつなぐ
// edy
//
// 2016/02/13:内部コンパレータを使う
// 2016/02/14:内部基準電圧を使う
//
//参考にしたサイト:コンパレータ割り込み minori246さん
//http://minori246.blog.fc2.com/blog-entry-15.html
//
//参考にしたサイト:パルス列終了検出 ラジオペンチさん 
//http://radiopench.blog96.fc2.com/blog-entry-640.html
//
#ifndef cbi
#define cbi(sfr, bit) (_SFR_BYTE(sfr) &= ~_BV(bit)) //clear
#endif
#ifndef sbi
#define sbi(sfr, bit) (_SFR_BYTE(sfr) |= _BV(bit)) //set
#endif

#include <LiquidCrystal.h>

LiquidCrystal lcd(4, 3, 8, 9, 10, 11); //LiquidCrystal(rs, enable, d4, d5, d6, d7)

volatile unsigned int count = 0;
unsigned int LASTcount = 0;
char s[16];
float temp;

void setup()
{
  lcd.begin(16, 2);
  initComp();
  lcd.setCursor(0, 0);
  lcd.print("Start LMT01");
  delay(1000);
  lcd.setCursor(0, 0);
  lcd.print("           ");
}

void loop()
{
  if (count != 0) {                  // カウンタがゼロではない場合、つまりカウント中なら
    while (count != LASTcount) {     // もし数値が変わっていたらまだ測定中なので以下を繰り返す
      LASTcount = count;             // 次回の比較用に値を保存
      delay(2);                      // ちょっと待つ
    }

    // パルス数表示
    dtostrf(count, 6, 0, s);
    lcd.setCursor(0, 0) ;
    lcd.print(s) ;

    // 温度表示
    temp = count / 16.0 - 50.0;
    dtostrf(temp, 6, 1, s);
    lcd.setCursor(0, 1) ;
    lcd.print(s) ;
    lcd.print("c") ;

    count = 0;                       // 次回のためにカウンターをリセット
  }
}

void initComp()
{
  cbi(ACSR, ACD);   // Analog Comparator Disable : コンパレータを使う設定にする
  sbi(ACSR, ACBG);  // Analog Comparator Bandgap Select : 内部基準電圧(1.1V)を使う設定にする
  sbi(ACSR, ACIE);  // Analog Comparator Interrupt Enable : コンパレータ割り込みを許可する
  cbi(ACSR, ACIC);  // Analog Comparator Input Capture Enable
  sbi(ACSR, ACIS1); // Analog Comparator Interrupt Mode Select1 : コンパレータの立下りで割り込み設定
  cbi(ACSR, ACIS0); // Analog Comparator Interrupt Mode Select0 : コンパレータの立下りで割り込み設定
  sbi(PRR, PRADC);  // オリジナルではcbi(PRR0, PRADC);だったがエラーになった。
  cbi(ADCSRB, ACME);  //Analog Comparator Multiplexer Enable : コンパレータ反転入力をAIN1にする
}

ISR(ANALOG_COMP_vect) {
  count++;
}

関連記事
スポンサーサイト

コメント

コメントの投稿

管理者にだけ表示を許可する

トラックバック

この記事へのトラックバックURL
http://edycube.blog.fc2.com/tb.php/870-6fc5f7c8

 | HOME | 

文字サイズの変更

プロフィール

edy

最新記事一覧(サムネイル画像付き)

DABP発振回路を使ってキャパシタのESRを測定する構想(2)断念 2018/02/15
Androidアプリ:Resonance Calculator LC共振回路の計算に便利 2018/02/03
DABP発振回路を使ってキャパシタのESRを測定する構想(1)追記あり 2018/01/27
スマホとmicro:bitをBluetoothでつなぎたいのだが・・・。 2018/01/27
Androidアプリ:Signal Generator 2017/12/31
エレコム EHP-AHR192 を試す。(1) 2017/12/17
AliExpressでお買い物:TPS60403テスト 2017/12/02
AliExpressでお買い物:スイッチトキャパシタ電圧コンバータ三種(1) 2017/11/29
ATmega328 Maximum Frequency vs. VCC 2017/11/26
AC電力計(2) 2017/11/19

全記事表示リンク

全ての記事を表示する

リンク

このブログをリンクに追加する

月別アーカイブ

02  01  12  11  10  09  08  07  06  05  04  03  02  01  12  11  10  09  08  07  06  05  04  03  02  01  12  11  10  09  08  07  06  05  04  03  02  01  12  11  10  09  08  07  06  05  04  03  02  12  11  10  09  07  05  04  03  04  03  01  12  11  10  08  07  06  05  03  02  01  12  11  10  09  08  07  06  05  04  03  02  01  12  11  10  09  08  07  06  05  04  02  01  12  10  09  08  07  06  05  04  03  02  01  12  11  10  09  08  07  06  05  03  02  01  12  11  10  09  08  07  06  05  04  03  02  01  12  10  09  08  07  06  05  04  03  02  01 

カテゴリ

プログラミング (0)
freescale (1)
AVR (3)
テルミン (16)
緊急警報放送 (3)
78K (1)
PSoC (295)
地上デジタル放送 (2)
電子工作 (434)
HX711 (2)
ACS712 (6)
数学 (6)
パソコン (12)
PLC (14)
未分類 (39)
ブログ関係 (20)
スカイプ (37)
ロボット (1)
LTSpice (8)
OCXO (0)
arduino (32)
maxima (1)
フランクリン発振回路 (3)
GPS (3)
DTMF (1)
Linux (1)
KOMAINO (7)
Android (1)

タグリスト

最近のコメント

最近のトラックバック

メールフォーム

名前:
メール:
件名:
本文:

検索フォーム

アクセス

RSSリンクの表示

ブログリンク

FC2Ad

まとめ

Template by たけやん